salvare downloads differenziati per tipo

[Pogechi]

salve, vorrei integrare questa funzione su safari: praticamente, se il file è un'immagine, salvarla tra le immagini, se è un video, tra i video, etc etc.

come posso fare? diciamo che le tipologie sarebbero: pdf, doc, xls, ppt, exe, dmg, immagini, video, audio

grazie in anticipo

[jeby]

si potrebbe fare un'azione cartella con applescript, ma sinceramente non ci ho mai provato!

[Pogechi]

ma con automator non è proprio possibile? già io non sono un asso in programmazione...alla fine credo sia una funzione utile. io avevo pensato, giacché i file me li scarica sulla scrivania, di fare un'azione tipo redirect o come si chiama, vale a dire spostare il file a seconda dell'estensione, con variabili IF (sto bestemmiando in linguaggio di programmazione...)

[Alexander De Large]

salve, vorrei integrare questa funzione su safari: praticamente, se il file è un'immagine, salvarla tra le immagini, se è un video, tra i video, etc etc.

come posso fare? diciamo che le tipologie sarebbero: pdf, doc, xls, ppt, exe, dmg, immagini, video, audio

grazie in anticipo

Già realizzata : se vuoi te la passo....anzi :

property movieExtList : {"mov", "mpg", "mp4", "avi", "ogm", "m4v", "mpeg"}
property musicExtList : {"m4a", "mp3", "ogg", "aiff", "aif", "wav"}
property folder_video : "Macintosh HD:Users:tuoAccount:Movies"
property folder_foto : "Macintosh HD:Users:tuoAccount:Pictures"
property folder_musica : "Macintosh HD:Users:tuoAccount:Music"

property myDelay : 5

property myAchiveFolder : "Macintosh HD:Users:tuoAccount:CartellaDoveFinisconoDownloadDaSafari" as alias

on adding folder items to this_folder after receiving these_items
tell application "Finder"
repeat with i from 1 to number of items in these_items
set downloadedFile to item i of these_items
set the theFileInfo to the info for downloadedFile

set oldFileSize to 0
set fileSize to the size of theFileInfo
repeat while fileSize is not equal to oldFileSize
set oldFileSize to fileSize
delay myDelay
set the theFileInfo to the info for downloadedFile
set fileSize to the size of theFileInfo
end repeat

if the name extension of the theFileInfo is in the graphicExtList then
-- move it to the user's pictures folder
move downloadedFile to folder_foto

else if the name extension of the theFileInfo is in the movieExtList then
-- move it to the user's movie folder
move downloadedFile to folder_video

else if the name extension of the theFileInfo is in the musicExtList then
-- move it to the user's music folder
move downloadedFile to folder_musica


end if
end repeat

end tell
end adding folder items to

Tutto ciò lo copi/incolli in AppleScritp e lo salvi. Quindi lo metti nella cartella Library/Scripts/Folder Action Scripts.

Quindi alla cartella dove finiscono i file scaricati alleghi (applichi) l'azione cartella di questo script

P.S. IMPORTANTE : lo script devi inserirlo dove ti ho indicato io, cioè nella Libreria del Sistema e NON in quella utente o non ti funziona nulla

[jeby]

uuuh! Molto simpatico!! Mi sa che lo userò anch'io, con qualche aggiunta (ad esempio per i file torrent)!!! Grazie!

[Alexander De Large]

uuuh! Molto simpatico!! Mi sa che lo userò anch'io, con qualche aggiunta (ad esempio per i file torrent)!!! Grazie!

C'erano....

[Pogechi]

grande! ora farò come detto e lo provo subito!!

[Pogechi]

scusa la pignoleria, ma non manca in alto la lista delle foto?

[jeby]

scusa la pignoleria, ma non manca in alto la lista delle foto?

sì bravo! Vedi, così stimola anche a cavarsela da soli!

[Alexander De Large]

scusa la pignoleria, ma non manca in alto la lista delle foto?

è vero! perdonami....ecco qua :

property graphicExtList : {"jpg", "gif", "png", "tiff", "jpeg", "pict"}


Aggiungilo in cima